#
#  This awk script will take the information from bjobs -l -uall on agave.tamu.edu and display it in column format
#
#  This script was created by Lisa M. Perez at the Laboratory for Molecular Simulation and is provided as is and may give incorrect
#     results periodically.
#
#  Please e-mail Lisa M. Perez at mouse@mail.chem.tamu.edu with problems.
#
#  To use this script you should make an alias in your .cshrc or .login file:  
#
#  alias qa 'bjobs -l -uall | awk -f ~/bjobs.awk'
#    
#  This alias implies that you put bjobs.awk in your home directory and you will type qa to execute
#
#  last updated 11/13/03
#

BEGIN { FS="<|>";i=0
print "                                                  Time                   Time                 CPU    CPU  MEM(MB) MEM(MB) Queue    S "
print "   User    Job ID           Job Name            Submitted               Started        Proc  Limit  Used   Req     Used "
print "----------------------------------------------------------------------------------------------------------------------------------------"}

# read in the information to the array head
# each line between User and SCHEDULING will be appended
/User/,/SCHEDULING/ {
if (/User/) {i=i+1} 
temp=$0
sub (/^ */, "",temp)
head[i]=head[i]temp
}

END {
for (l=1;l<=i;l++) {
# split each record into fields with dividers <  > and ,
split(head[l],a,FS="<|>|,")
for (k=1;k<=50;k++) { 

# Get the user name
if ( a[k] ~ /User/ ) U[l] = (a[k+1])

# Get the Job ID
if ( a[k] == "Job ") J[l] = (a[k+1])

# Get the Job Name if there is one
if ( a[k] ~  /Job Name/ ) JN[l] = (a[k+1])

# Get the Status
if ( a[k] ~ /Status/ ) S[l] = (a[k+1])

# Get the Queue
if ( a[k] ~ /Queue/ ) Q[l] = (a[k+1])

### MEMORY ###
# Get the Memory of running jobs
if ( a[k] ~ /MEM:/ ) {split(a[k],b,FS="MEM: | Mbytes");UM[l] = (b[2])}

# Get the Memory Limit of Queued jobs
if ( a[k] ~ /MEMLIMIT/ ) {split(a[k],b,FS="MEMLIMIT| K");ML[l] = (b[2]/1000)}

# Get the Requested Memory 
if ( a[k] ~ /-M/ ) {x=split(a[k],b,FS="")}
for (n=1;n<x;n++) {
if (b[n] ~ /-M/){RM[l]=(b[n+1]/1000)}
}
### END MEMORY ###

# Get the CPU time used for running jobs
if ( a[k] ~ /CPU time/ ) {split(a[k],b,FS="is | seconds");CPU[l]=(b[2]/3600);CPU1[l]=(b[2]%3600)}

# Get the CPU limit specified for the queue
if ( a[k] ~ /CPULIMIT/ ) {split(a[k],b,FS="CPULIMIT | min");CPULIM[l]=(b[2]/60)}

# Get the CPU requested
if ( a[k] ~ /-c/ ) {split(a[k],b,FS=" -c|:");RCPU[l]=b[2]}

# Get the number of processors requested
if ( a[k] ~ /Processors Requested/ ) {split(a[k],b,FS="Processors");P[l] = (b[1])}

# Get the time the jobs was started
if ( a[k] ~ /Started on/ ) {
  if (a[k] ~ /MEMLIMIT/){split(a[k],b,FS="K|Started");Start[l] = (b[2])} else
  {split(a[k],b,FS="Requested;|Started|tam");Start[l]=(b[2])}
  }

# Get the time the jobs was submitted
if ( a[k] ~ /Submitted from host/ ) {split(a[k],b,FS="Submitted");Submit[l]=(b[1])}
  }

# reassign S[l] to be R or Q instead of Running or Pending
if (S[l] == "RUN") {S[l]="R"} else 
{S[l]="Q"}

# assign the job name to username_job if a job name does not exist
if (! JN[l]) {JN[l]=U[l]"_job"}

# assign the requested memory instead of the memory limit or running memory if it exists
if (RM[l]) {M[l]=RM[l]}

# assign the requested processors to 1 if P doesn't exist
if (! P[l]) {P[l]=1}

# assign the cpulimit for hpc_ibm and hpc_ibm-e if they are not assigned because they don't show up in the bjobs -l -uall output
if ((! RCPU[l]) && (! CPULIM[l]) && (Q[l] == "hpc_ibm")) { CPULIM[l]=500}
if ((! RCPU[l]) && (! CPULIM[l]) && (Q[l] == "hpc_ibm-e")) { CPULIM[l]=200}

# assign the memory for hpc_ibm and hpc_ibm-e if they are not assigned because they don't show up in the bjobs -l -uall output
if ((! RM[l]) && (! ML[l]) && (Q[l] == "hpc_ibm")) { ML[l]=8000}
if ((! RM[l]) && (! ML[l]) && (Q[l] == "hpc_ibm-e")) { ML[l]=8000}

# assign the requested cpu time instead of the cpu limit if it exists
if (RCPU[l]) {CPULIM[l]=RCPU[l]}

# assign the Memory limit if requested memory is not available
if (! RM[l]) {M[l]=ML[l]}

# add up the number of processors asked for
if (S[l] == "R") {p = p + P[l]}

# print the results
printf "%8.8s %7.7s %25.25s %22.22s %22.22s %1d %6.6s %4.0f:%2.2s %6.6s %6.6s %8.8s %3.3s \n", 
U[l],J[l],JN[l],Submit[l],Start[l],P[l],CPULIM[l],CPU[l],CPU1[l],M[l],UM[l],Q[l],S[l]


 }
print ""
print "Total CPUS = "p
print ""
system("uptime")
print ""
}